// original code by robert hodgin
// see: http://processing.org/discourse/yabb/YaBB.cgi?board=Contribution_Simlation;action=display;num=1078114794

// added parts of the code are marked [toxi040303]

float noiseVal;
float noiseScale = 0.005;
float noiseCount = 0.0;
float noiseSpeed = 0.005;

float xCount, xSpeed;
float yCount, ySpeed;

float theta;
float angle;
float angleDelta;
float xv, yv;
float speed = 10;

boolean lines = false;

int noiseRes = 2;

Vehicle[][] vehicle;

int xSize = 400;
int ySize = 600;

int xTotal = int(xSize / noiseRes);
int yTotal = int(ySize / noiseRes);

// [toxi040303] overlay image object
BImage ov=new BImage(10,10);

void setup(){
  size(xSize,ySize);
  smooth();
  ellipseMode(CENTER_DIAMETER);
  colorMode(HSB, 360);

  vehicle = new Vehicle[yTotal][xTotal];
  for (int y=0; y<yTotal; y++){
    for (int x=0; x<xTotal; x++){
      vehicle[y][x] = new Vehicle(x, y);
    }
  }
  
  // turn on bilinear filtering for overlay image
  ov.smooth=true;
}

void loop() {
  background(0);

  xSpeed = ((width/2) - mouseX)/10.0f;
  ySpeed = ((height/2) - mouseY)/10.0f;

  xCount += xSpeed;
  yCount += ySpeed;

  if (mousePressed){
    noiseDetail(6, .5f);
    noiseScale -= (noiseScale - 0.02) * .2;
  } else {
    noiseDetail(2, .5f);
    noiseScale -= (noiseScale - 0.005) * .2;
  }

  for(int y=0; y<=height; y++) {
    for(int x=0; x<=width; x++) {

      if (x%noiseRes == 0 && y%noiseRes == 0){
        noiseVal=noise((x - xCount)*noiseScale, (y - yCount)*noiseScale, noiseCount);
        float g = noiseVal*720.0f;
        theta = (-(g * PI))/180.0f;
        xv = cos(theta) * speed;
        yv = sin(theta) * speed;

        if (lines){
          stroke(g - 180, 360, 360, 20);
          line (x - (xv/2), y - (yv/2), x, y);
        }
        //point(x - xv, y - yv);
        //stroke(255,0,0, 25);
        //line (x + (xv), y + (yv), x, y);
      }
    }
  }

  noiseCount += noiseSpeed;
  for (int y=0; y<yTotal; y++){
    for (int x=0; x<xTotal; x++){
      vehicle[y][x].exist();
    }
  }

  // [toxi040303] taken from "superGlow"...
  // creates a 10x10 version of the current screen
  ov.replicate(g,0,0,width,height,0,0,10,10);
  // uses itself as alpha channel to use bright areas only
  ov.alpha(ov);
  // adds itself to the current screen image
  blend(ov,0,0,9,9,0,0,width,height,ADD);
  
  if (keyPressed && key==SHIFT) 
  saveFrame("fur-####.tga");
  
  // give cpu time to breath
  delay(10);
}

void keyPressed(){
  if (key == ' '){
    if (lines){
      lines = false;
    } else {
      lines = true;
    }
  }
}

class Vehicle {
  float x;
  float y;

  float xv, yv;
  float xf, yf;

  float theta;
  float angle;
  float angleDelta;
  float speed = random(2.0f, 10.0f)*0.5;
  
  // [toxi040303] assign slightly randomized base colour for each particle
  float hue=25+random(15);
  float sat=(random(1)<0.15 ? 30 : 150)+random(150);
  float bri=random(100);
  
  Vehicle (int xSent, int ySent){
    x = xSent * noiseRes;
    y = ySent * noiseRes;
  }

  void exist(){
    findVelocity();
    move();
    render();
  }

  void findVelocity(){
    noiseVal=noise((x - xCount)*noiseScale, (y - yCount)*noiseScale, noiseCount);
    angle -= (angle - noiseVal*720.0f) * .2f;
    theta = (-(angle * PI))/180.0f;
    xv = cos(theta) * speed;
    yv = sin(theta) * speed;
  }

  void move(){
    x -= xv;
    y -= yv;

    if (x < -50){
      x += width + 100;
    } else if (x > width + 50){
      x -= width + 100;
    }

    if (y < -50){
      y += height + 100;
    } else if (y > height + 50){
      y -= height + 100;
    }

  }

  void render(){
    // [toxi040303] check if line's angle is currently on the bright or dark side
    // the light direction is set to 340 degrees
    // the closer the line's angle is to the light's, the brighter its colour
    if (angle>70 && angle<250) stroke(hue, sat,bri+angle*1.5,20);
    else {
      // find distance to light and normalize to use as impact factor
      float f=abs(340-(angle<90 ? angle+360 : angle))/90;
      // base colour on factor
      // colour desaturates and brightens towards the light
      stroke(hue, sat*(0.5+f/2),bri+angle*(2-f),20+(1-f)*20);
    }
    // draw longer lines
    line(x,y, x+(xv*20), y+(yv*20));
  }
}