// Processing XML parsing example
// using nanoXML library by cyberElf (http://web.wanadoo.be/cyberelf/nanoxml/)
// author: info at toxi.co.uk
//
// for questions, please consult NanoXML javadocs

Object[] places;
XMLElement xml;

void setup() {
  size(400,300);
  textFont(loadFont("Franklin_Gothic_Medium.vlw"),24);
  // load & parse XML
  xml = new XMLElement();
  String xmlString="";
  String[] lines=loadStrings("test.xml");
  for(int i=0; i<lines.length; i++) xmlString+=lines[i];
  xml.parseString(xmlString);
  // retrieve all childnodes and store them in an array
  places=xml.getChildren().toArray();
}

void draw() {
  int currX=10,currY=30;
  rectMode(CORNERS);
  background(0xe0);
  fill(0);
  // display date attribute of root node
  text((String)xml.getAttribute("date"),currX,currY);
  textSize(12);
  fill(0x80); stroke(0x80);
  currY+=30;
  // draw temperature scale
  for(int t=-20; t<=25; t+=2) {
    if ((t%10)==0) {
    line(currX,currY,currX,currY+20);
    text(t,currX,currY+30);
    } else line(currX,currY,currX,currY+10);
    currX+=16;
  }
  currX=10;
  currY+=80;
  // draw bar charts with details
  textSize(18);
  noStroke();
  for(int i=0; i<places.length; i++) {
    XMLElement node=(XMLElement)places[i];
    int temp=node.getIntAttribute("temp");
    fill(64+temp*8,128+temp*2,128-temp*8);
    rect(currX,currY-40,currX+(temp+20)*8,currY);
    fill(0xff);
    text((String)node.getAttribute("id"),currX+5,currY-20);
    text(node.getContent(),currX+5,currY-6);
    currY+=50;
  }
}